Prijeđite na sadržaj

Postavke kolačića

Za svaku vrstu odaberite koje kolačiće dopuštate. Svoj odabir uvijek možete promijeniti putem poveznice Postavke kolačića na dnu svake stranice. Izjava o privatnosti

Nužni

Uvijek uključeni

Potrebni za prijavu, čuvanje košarice i pamćenje Vaših odabira. Uvijek su uključeni.

Koji kolačići?
  • weboke_sessie, weboke_klant, weboke_remember: Vaša sesija i to da ostanete prijavljeni
  • weboke_basket: Vaša košarica
  • wkBtwIncl: prikaz cijena s PDV-om ili bez njega
  • wok_cookies: Vaš odabir kolačića, 12 mjeseci

Mjeri koji oglas dovodi do posjeta ili narudžbe, kako ne bismo plaćali oglase koji ništa ne donose.

Koji kolačići?
  • Google Ads putem Google Tag Managera (_gcl_au, _gcl_aw), do 90 dana
  • OpenAI Ads, oglasi u ChatGPT-u
  • wok_aff: preko kojeg ste partnera došli k nama (partnerski program), 60 dana

4,6

Država i jezik

Svaka država ima vlastitu stranicu, s cijenama i PDV-om te države.

Pogledajte

Twee lijsten vergelijken: wie staat er wel in de ene en niet in de andere?

Ovaj članak još nije preveden. Čitate nizozemsku verziju.

De ledenlijst tegen de betalingen, de klanten van vorig jaar tegen die van dit jaar, de voorraadlijst tegen de bestelling: je wilt weten wie er in de ene lijst staat en niet in de andere. Pronalaženje i uklanjanje dupliciranih kupaca zoekt dubbelen binnen één lijst; hier vergelijk je twee lijsten met elkaar.

Als voorbeeld nemen we Bakkerij De Korenaar met twee werkbladen: Klanten2025 met de e-mailadressen van vorig jaar in A2:A8, en Klanten2026 met die van dit jaar in A2:A7.

Manier 1: een hulpkolom met weg of blijft

Typ op het werkblad Klanten2025 in B2:

=ALS(AANTAL.ALS(Klanten2026!$A$2:$A$7;A2)=0;"weg";"blijft")

Trek de formule door tot de laatste klant. AANTAL.ALS telt hoe vaak het adres in de lijst van 2026 voorkomt. Is dat 0, dan is de klant weg. Daarna kun je op kolom B filteren of sorteren (zie Sortiranje i filtriranje).

De dollartekens zijn belangrijk: zonder dollartekens schuift het bereik in de andere lijst mee bij doortrekken, en vallen de bovenste adressen er onderaan uit.

Manier 2: een lijst met alleen de verschillen

Op een apart werkblad maakt FILTER in één keer een lijst van alle vertrokken klanten:

=FILTER(Klanten2025!A2:A8;AANTAL.ALS(Klanten2026!A2:A7;Klanten2025!A2:A8)=0;"niemand weg")

Hier krijgt AANTAL.ALS een hele lijst als tweede onderdeel en telt het voor elk adres van 2025 tegelijk. FILTER houdt de adressen over waarvoor dat 0 is. De nieuwe klanten vind je door de lijsten om te draaien:

=FILTER(Klanten2026!A2:A7;AANTAL.ALS(Klanten2025!A2:A8;Klanten2026!A2:A7)=0;"niemand nieuw")

Vertrokken en nieuwe klanten naast elkaar
Vertrokken klanten (1) en nieuwe klanten (2), elk met één FILTER-formule

Wie in maar één van beide lijsten staat, nieuw of vertrokken, krijg je met:

=UNIEK(VERT.STAPELEN(Klanten2025!A2:A8;Klanten2026!A2:A7);;1)

VERT.STAPELEN zet de twee lijsten onder elkaar. UNIEK met een 1 als derde onderdeel houdt alleen de waarden over die precies één keer voorkomen. Staat een adres binnen één lijst al dubbel, maak die lijst dan eerst uniek: =UNIEK(VERT.STAPELEN(UNIEK(Klanten2025!A2:A8);UNIEK(Klanten2026!A2:A7));;1).

Manier 3: kleuren in plaats van lijsten

  1. Selecteer op het werkblad Klanten2025 de adressen, A2:A8.
  2. Kies op het tabblad Start Conditionele opmaak, Nieuwe regel, soort Formule.
  3. Typ =AANTAL.ALS(Klanten2026!$A$2:$A$7;$A2)=0, kies een opvulkleur en klik op OK.

Een verwijzing naar een ander werkblad in een opmaakregel werkt in Euro-Office gewoon; in oude Excel-versies moest dat via een benoemde naam.

Vertrokken klanten gekleurd
Adressen die in 2026 niet meer voorkomen kleuren oranje; kolom B zegt weg of blijft

Valkuilen

  • Spaties: "info@dekorenaar.nl " met een spatie erachter is voor de spreadsheet een ander adres. Ruim spaties eerst op met SPATIES.WISSEN in een hulpkolom.
  • Lege cellen in een bereik tellen ook mee als waarde. Neem dus alleen de rijen met gegevens, of filter lege cellen weg met <>"".
  • Getallen tegen tekst: vergelijk je klantnummers en staat het nummer in de ene lijst als tekst (links in de cel) en in de andere als getal, dan vinden ze elkaar niet. Zie VLOOKUP vraća #N/A: evo kako to riješiti.
  • Typ geen WAAR zonder haakjes als derde onderdeel van UNIEK; Euro-Office kent alleen TRUE, WAAR() of 1 (zie Preuzimanje formula iz Excela: engleski nazivi funkcija i točka zarez).

Trenutak…

Postavite svoje domene

Za svaku domenu odredite nameservere, povezivanje s hostingom i tko postaje vlasnik.

Učitavanje Vaših domena…